##############################################
### Daft Punk Aibo Dance (Long version),   ###
### made by Ricardo Tellez		   ###
### from a previous version of Diego Pardo ###
##############################################

stop events; noop;// prevents previous 'at' commands to superimpose

mouth.val->blend    = mix;
headTilt.val->blend = mix;
headPan.val->blend  = mix;

group ledCabeza   { ledF1,ledF2,ledF3,ledF4,ledF5,ledF6,ledF7,
                    ledF8,ledF9,ledF10,ledF11,ledF12,ledF13,ledF14 };
group Orejas      { earL, earR };
group ledEspecial { ledF1,ledF2,ledF13,LedF14 };

ledCabeza.val->blend = mix;


if (isdef(Inicial)) 
{
  undef Inicial;
  undef mov1;
  undef Cabeza;
  undef Chispun;
  undef Chislado;
  undef LucesCabeza;
  undef boca;
  undef boca2;
  undef onda;
  undef cuello;
  undef Abrebrazos;
  undef Subebaja;
  undef sentar;
  undef brazos;
  undef doblarodillas;
  undef IrBajando;
  undef LucesBajando;
  undef Travolta;
  undef Travolta2;
  undef ladolado;
  undef Luztravolta;
  undef Luztravolta2;
  undef LuzRojabit;
  undef LuzCentro;
  undef moverorejas;
};


def Inicial()
{
   headPan.val'n  = 0.5 smooth:1000,
   headTilt.val'n = 0.4 smooth:1000,
   neck.val'n     = 0.2 smooth:1000,

   legRF1.val'n   = 0.6 smooth:1000,
   legRF2.val'n   = 0   smooth:1000,
   legRF3.val'n   = 0.3 smooth:1000,
   
   legLF1.val'n   = 0.4      smooth:1000,
   legLF2.val'n   = 0.145473 smooth:1000,
   legLF3.val'n   = 0.99     smooth:1000,

   legLH1.val'n   = 0.281059 smooth:1000,
   legRH1.val'n   = 0.349205 smooth:1000,

   legLH2.val'n   = 0.015000 smooth:1000,
   legRH2.val'n   = 0.011740 smooth:1000,

   legLH3.val'n   = 0.975802 smooth:1000,
   legRH3.val'n   = 0.964802 smooth:1000,

   ledCabeza.val'n = 0;

   mouth.val'n = 1 smooth:1000;
   modeB.val   = 0;
   modeR.val   = 0;
   modeG.val   = 0;
   ledWifi.val = 0;
};


def mov1()
{
   ledF14.val'n  = 1;
   legRF2.val'n  = 1   smooth:500 &
   headPan.val'n = 0.1 smooth:500;
};


def Cabeza()
{
   timeout(2s) headTilt.val'n = 0.4 sin:457 ampli:0.1;
   timeout (3s) headTilt.val'n = 0.4 sin:457 ampli:0.1 &
   headPan.val'n  = 0.5 smooth:2000;
};   


def Chispun(j)
{
   timeout(j) headTilt.val'n = 0.4 sin:457 ampli:0.15;
};   

def Chislado(j)
{
   timeout(j) headPan.val'n=0.5 sin:700 ampli:0.15;
};   



def LucesCabeza()
{
 for(i=0;i<3;i++)
 {
   ledHC.val=1;
   wait(457);
   ledHC.val=0;
   ledHW.val=1;
   wait(457);
   ledHW.val=0;
   wait(457);
 };

};


def boca()
{
   global.ledMode=0;
   ledCabeza.val=1 &
   mouth.val'n=0.1 smooth:100;
   mouth.val'n=0.6 smooth:100;
   ledCabeza.val=0;
};

def boca2()
{
   global.ledMode=1;
   ledEspecial.val=1 &
   mouth.val'n=0.1 smooth:100;
   mouth.val'n=0.6 smooth:100;
   ledEspecial.val=0;
};



def onda()
{
  legLF2.val'n=0.08,
  legRF2.val'n=0.08,
  modeR.val=0,
  modeB.val=0,
  modeG.val=0,
    
  for(i=0;i<4;i++)
  { 
   earL.val=0,
   earR.val=0,
   modeR.val=0;

   legLF1.val'n=0.6 smooth:250 &
   legRF1.val'n=0.45 smooth:250;

   legLF3.val'n=0.60 smooth:200 &
   legRF3.val'n=0.15 smooth:200;

   legLF1.val'n=0.45 smooth:250 &
   legRF1.val'n=0.6 smooth:250;

   legLF3.val'n=0.15 smooth:200 &
   legRF3.val'n=0.60 smooth:200;
   earL.val=1 &
   earR.val=1 &
   modeR.val=1;

  };
  
  earL.val=0;
  earR.val=0;
  
  {legLF1.val'n=0.55 smooth:250 &
  legRF1.val'n=0.55 smooth:250};

  {legLF3.val'n=0.50 smooth:250 &
  legRF3.val'n=0.50 smooth:250};

  modeR.val=0;
  modeB.val=1;
};

def cuello()
{
   timeout(4s) neck.val'n=0.2 sin:600 ampli:0.15;
   neck.val'n=0.1 smooth:150;
};

def Abrebrazos()
{
   legLF2.val'n=0.99 smooth:457 &
   legRF2.val'n=0.99 smooth:457 ;
   legLF3.val'n=0 smooth: 457 &
   legRF3.val'n=0 smooth: 457 ;

   wait(100);
};

def Subebaja()
{

   timeout(2s) legRF3.val'n=0.3 sin:914 ampli:0.2 &
   timeout(2s) legLF3.val'n=0.3 sin:914 ampli:0.2;
};

def sentar()
{
   legRF1.val'n=0.48  smooth:800,   
   legRF2.val'n=0.060653 smooth:800,
   legRF3.val'n=0.189336 smooth:800,


   legLF1.val'n=0.415589 smooth:800,   
   legLF2.val'n=0.060653 smooth:800,
   legLF3.val'n=0.189336 smooth:800,

   legRH1.val'n=0.218318 smooth:900,   
   legRH2.val'n=0.37826 smooth:900,
   legRH3.val'n=0.858136 smooth:900,


   legLH1.val'n=0.218318 smooth:900,   
   legLH2.val'n=0.37826  smooth:900,
   legLH3.val'n=0.858136 smooth:900;
};





///////////////// MAIN ///////////////////

def brazos()
{
   {timeout(4.5s) legRF1.val'n=0.6 sin:457 ampli:0.05 &
    LucesCabeza() &  // IMPORTANTE
    timeout(4s) legLF1.val'n=0.6 sin:457 phase:3.1415962 ampli:0.05
   };
   

   {Chispun(4000) & {Abrebrazos(); Subebaja()} } ;
 
   onda() ;
    

   {legRF1.val'n=0.48  smooth:800,   
   legRF2.val'n=0.060653 smooth:800,
   legRF3.val'n=0.189336 smooth:800,


   legLF1.val'n=0.415589 smooth:800,   
   legLF2.val'n=0.060653 smooth:800,
   legLF3.val'n=0.189336 smooth:800,};

  earL.val=0;
  earR.val=0;
};

  

/////////////////////////////////////////////








def doblarodillas()
{
   timeout(3s) legLF3.val'n=0.3 sin:457 ampli:0.1, 
   timeout(3s) legRF3.val'n=0.3 sin:457 ampli:0.1;
};


def IrBajando()
{

  legRH1.val'n=0.15 smooth:3000 &
  legLH1.val'n=0.15 smooth:3000
};


def LucesBajando()
{
  ledCabeza.val=0;

  for(i=0;i<4;i++)
  {
    global.ledMode=0;
    ledF14.val=1 & ledF13.val'n=1;
    wait(250);
    ledF14.val=0 & ledF13.val'n=0;
    ledF12.val=1 & ledF11.val'n=1;
    wait(200);
    ledF12.val=0 & ledF11.val'n=0;
    global.ledMode=1;
    ledF13.val=1 & ledF14.val'n=1; 
    ledF1.val=1 & ledF2.val'n=1; 
    ledF3.val=1 & ledF4.val'n=1; 
    wait(250);
    ledF13.val=0 & ledF14.val'n=0; 
    ledF1.val=0 & ledF2.val'n=0; 
    ledF3.val=0 & ledF4.val'n=0; 
    wait(200);
  };
  ledCabeza.val=1;
};


def Travolta()
{
   legRF1.val'n=0.75 smooth:457,
   headTilt.val'n=0.5 smooth:457,
   headPan.val'n=0.5 smooth:457,
   neck.val'n=0.2 smooth:457 |

   for(i=0;i<2;i++)
   {
      
      {legRF1.val'n=0.95 smooth : 325,
      legRF2.val'n=0.4 smooth  :325,
      headPan.val'n=0.1 smooth  :325,
      headTilt.val'n=0.90 smooth :325;
      wait(50)};
      {legRF1.val'n=0.75 smooth :325,
      legRF2.val'n=0.02 smooth :325,
      headPan.val'n=0.5 smooth :325,
      headTilt.val'n=0.5 smooth :325;
      wait(50)};
   };

   legRF1.val'n=0.5 smooth:457;
};


def Travolta2()
{
   legLF1.val'n=0.75 smooth:457,
   headTilt.val'n=0.5 smooth:457,
   headPan.val'n=0.5 smooth:457,
   neck.val'n=0.2 smooth:457 |

   for(i=0;i<2;i++)
   {
      
      {legLF1.val'n=0.95 smooth : 325,
      legLF2.val'n=0.4 smooth  :325,
      headPan.val'n=0.9 smooth  :325,
      headTilt.val'n=0.90 smooth :325;
      wait(50)};
      {legLF1.val'n=0.75 smooth :325,
      legLF2.val'n=0.02 smooth :325,
      headPan.val'n=0.5 smooth :325,
      headTilt.val'n=0.5 smooth :325;
      wait(50)};
   };
   
   legLF1.val'n=0.5 smooth:457;
};

def ladolado()
{

   legRF2.val'n=0.15 smooth:600,
   legLF2.val'n=0.15 smooth:600,
   
   headTilt.val'n=0.5 smooth:600;
   Chislado(3000) &

   { timeout(3s) legRF3.val'n=0.2 sin:600 ampli:0.2&
     timeout(3s) legLF3.val'n=0.2 sin:600 ampli:0.2 phase:3.1415962}
};


def Luztravolta()
{
  ledF4.val=1;
  wait(100);
  ledF6.val=1;
  wait(100);
  ledF5.val=1;
  wait(100);
  ledF3.val=1;
  wait(50);

  ledF4.val=0;
  ledF6.val=0;
  ledF5.val=0;
  ledF3.val=0;

  ledF7.val=1;
  wait(100);
  ledF9.val=1;
  wait(100);
  ledF10.val=1;
  wait(100);
  ledF8.val=1;
  wait(50);

  ledF7.val=0;
  ledF9.val=0;
  ledF10.val=0;
  ledF8.val=0;
};



def Luztravolta2()
{
  ledF3.val=1;
  wait(100);
  ledF5.val=1;
  wait(100);
  ledF6.val=1;
  wait(100);
  ledF4.val=1;
  wait(50);

  ledF3.val=0;
  ledF5.val=0;
  ledF6.val=0;
  ledF4.val=0;

  ledF8.val=1;
  wait(100);
  ledF10.val=1;
  wait(100);
  ledF9.val=1;
  wait(100);
  ledF7.val=1;
  wait(50);

  ledF7.val=0;
  ledF9.val=0;
  ledF10.val=0;
  ledF8.val=0;
};

def LuzRojabit()
{
  global.ledMode=0;
  ledF14.val=1;
  ledF13.val=1;
  wait(850);
  ledF14.val=0;
  ledF13.val=0;
  wait(850);
};

def LuzCentro()
{
  global.ledMode=0;
  ledF11.val=1;
  ledF12.val=1;
  wait(850);
  ledF11.val=0;
  ledF12.val=0;
  wait(850);
};


def moverorejas()
{
  Orejas.val=1 &
  modeB.val=1;

  wait(100);

  Orejas.val=0 &
  modeB.val=0;

  wait(100);

  Orejas.val=1 &
  modeG.val=1;

  wait(100);

  Orejas.val=0 &
  modeG.val=0;

  wait(100);

  Orejas.val=1 &
  modeR.val=1;   

  wait(100);

  Orejas.val=0 &
  modeG.val=0;

  wait(100);
};

def right_side()
{
	legRF2.val = 20 smooth : 325 &
	legRH2.val = 20  smooth : 325 &
	legLF2.val = -15 smooth : 325  &
	legLH2.val = -15 smooth : 325 &
	legLF3.val=70 smooth : 325 &
	legLH3.val=75 smooth : 325;


	legRF2.val= 90 smooth:325 &

	loopn(5)
	{
		legRF3.val = 60 smooth:250;
		legRF3.val = 30 smooth:250;
	};


};

def left_side()
{
	legRF2.val = -15  smooth : 325 &
	legRH2.val = -15 smooth : 325  &
	legLF2.val = 20 smooth : 325  &
	legLH2.val = 20 smooth : 325  &
	legRF3.val=70 smooth : 325 &
	legRH3.val=75 smooth : 325 ;

	legLF2.val= 90 smooth:325  &

	loopn(5)
	{
		legLF3.val = 60 smooth:250;
		legLF3.val = 30 smooth:250;
	};


};
def center()
{
	legRF2.val = 0  smooth : 325 &
	legRH2.val = 0  smooth : 325 &
	legLF2.val = 0  smooth : 325 &
	legLH2.val = 0 smooth : 325 &
	legLH3.val =30 smooth : 325 &
	legRH3.val=30 smooth : 325;

};
def oscillatory_head(n)
{
	loopn (n)
	{
		headTilt.val = 40 time:500 &
		headPan.val = 0 time:500;

		headTilt.val = 10 time:500 &
		headPan.val = 30 time:500;
		
		headTilt.val = -20 time:500 &
		headPan.val = 0 time:500;

		headTilt.val = 10 time:500 &
		headPan.val = -30 time:500;

		headTilt.val = 40 time:500 &
		headPan.val = 0 time:500;

		headTilt.val = 10 time:500 &
		headPan.val = -30 time:500;

		headTilt.val = -20 time:500 &
		headPan.val = 0 time:500;

		headTilt.val = 0 time:500 &
		headPan.val = 30 time:500;

	};
};

def swing(num)
{
	for (i=0;i<num;i++)
	{
		legF3.val = 60 smooth:257  &
		legH3.val = 60 smooth:257 &
		legF1.val = -15 smooth:257 &
		legH1.val = -15 smooth:257;

		legF3.val = 30 smooth:257  &
		legH3.val = 30 smooth:257 &
		legF1.val = 0 smooth:257 &
		legH1.val = 0 smooth:257;
	};
};

def mystandup() 
{
   	legH1.val =  0 time:1000 &
    	legH2.val =  0 time:1000 &
    	legH3.val =  30 time:1000 &
	legF1.val =   0 time:1000 &
	legF2.val =   0 time:1000 &
	legF3.val =   30 time:1000 &
	tailTilt.val = 2 time:1000 &
	tailPan.val = 0 time:1000 &
	head.val = 0 time:1000;
};

def side_to_side()
{
	Chispun(7500),
	headPan.val= 10 &
	right_side();
	//wait(800);
	headPan.val= 0 &
	center();
	wait(300);
	moverorejas();
	//wait(1000);
	//swing(3);
	headPan.val= -10 &
	left_side();
	//wait(800);
	headPan.val= 0 &
	center();
	wait(300);
	moverorejas();
	//swing(3);
};

def toTheFront()
{

	legF1.val=-50 time:1000 &
	legF3.val=120 time:1000 &
	neck.val=-50 time:1000;

	legF3.val= 50 time:1000 &
	legH3.val = 50 time:1000 &
	legH1.val = 40 time:1000;

	mystandup();

};


def back_wave()
{
  legLH2.val=0,
  legRH2.val=0,
  modeR.val=0,
  modeB.val=0,
  modeG.val=0,
    
  for(i=0;i<5;i++)
  { 
   earL.val=0,
   earR.val=0,
   modeR.val=0;

   legLH1.val'n=0.6+0.25 smooth:250 &
   legRH1.val'n=0.45+0.25 smooth:250;

   legLH3.val'n=0.60 smooth:200 &
   legRH3.val'n=0.15 smooth:200;

   legLH1.val'n=0.45+0.25 smooth:250 &
   legRH1.val'n=0.6+0.25 smooth:250;

   legLH3.val'n=0.15 smooth:200 &
   legRH3.val'n=0.60 smooth:200;
   earL.val=1 &
   earR.val=1 &
   modeR.val=1;

  };
  
  earL.val=0;
  earR.val=0;
  
  {legLH1.val'n=0.55+0.25 smooth:250 &
  legRH1.val'n=0.55+0.25 smooth:250};

  {legLH3.val'n=0.50 smooth:250 &
  legRH3.val'n=0.50 smooth:250};

  modeR.val=0;
  modeB.val=1;
};


def upsidedown()
{

	legF1.val=-50 time:1000 &
	legF3.val=120 time:1000 &
	headPan.val=90 time:1000 &
	neck.val=-80 time:1000;

	legF1.val=-100 time:1000;

	legH1.val=-70 time:2000 &
	legF1.val=0 time:2000 &
	legH3.val=120 time:2000 &
	neck.val=3 time:2000;

	legH1.val=100 time:2000 &
	legH3.val=0 time:2000;

	back_wave();

	loopn (1)
	{
		legH1.val=50 time:300 &
		legH3.val=100 time:300;

		legH1.val=100 time:300 &
		legH3.val=0 time:300;	
	};

};

def wagtail()
{
	tailTilt.val = 2;
	tailPan.val = 0;
	timeout(15s) tailPan.val = 0 sin:600 ampli:20;
};

def descend()
{
	legH2.val = 0 time:1000 &
	legH3.val = 30 time:1000 &
	headPan.val = 0 time:1000;

	legF1.val = -100 time:2000 &
	neck.val= -30 time:2000;

	legF2.val = 0 time:1000 &
	legH3.val = 90 time:1000;

	legH2.val= 90 time:1000 ;
	//legF1.val= -120 time:1000 &
	//legF3.val = 30 time:1000;

	legF2.val= 90 time:1000 &
	legF3.val= 0 time:2000;

	robot.initial();
	robot.sit() &
	neck.val= -30 time:1000;
	
};

///////////////// CATCHING EVENTS /////////////////////

events:{
 
at &(speaker.remain=~=29025-20500 || speaker.remain=~=28775- 20500 || speaker.remain=~=28525- 20500 || speaker.remain=~=28325- 20500)
{
 boca(),
},


at &(speaker.remain=~=27125- 20500 || speaker.remain=~=26950 - 20500|| speaker.remain=~=26675- 20500 || speaker.remain=~=26425- 20500)   
{
 boca2(),
},


at(speaker.remain=~=29030- 20500)
{
  mov1(),   // Cabeza y Brazo a la Izquierda
},



at(speaker.remain=~=28550- 20500)
{
  legRF2.val'n=0 smooth:1000;
  legRF1.val'n=0.6 smooth:1000,
  legRF3.val'n=0.3 smooth:1000,
},


at(speaker.remain=~=28200- 20500)
{
  legLF1.val'n=0.55 smooth:300 &
  legLF2.val'n=0 smooth:300 &
  legLF3.val'n=0.3 smooth:300,

  Orejas.val=1 &
  modeB.val=1;

  wait(100);

  Orejas.val=0 &
  modeB.val=0;

  wait(100);

  Orejas.val=1 &
  modeG.val=1;

  wait(100);

  Orejas.val=0 &
  modeG.val=0;

  wait(100);

  Orejas.val=1 &
  modeR.val=1;   
},


at(speaker.remain=~=26225- 20500)
{
 Cabeza(),
 for(i=0;i<100;i++) { LuzRojabit(); LuzCentro();};

},

at(speaker.remain=~=26260- 20500)
{
 for(i=0;i<100;i++) 
 {
   LuzRojabit();
   LuzCentro();
 };

},



at(speaker.remain=~=25225- 20500)
{

 brazos();

 sentar();

 {doblarodillas() & Chislado(2800)};


 Travolta();
 Travolta2();
 ladolado() ;

{legH1.val = -80 time:500 &
legH2.val = 0 time:500};
	
legH1.val'n=0.218318 smooth:500;

{legF1.val=80 time:1000 &
legH2.val=0 time:1000};
wait(300);
mystandup();

{oscillatory_head(2) &
swing(16)};

side_to_side();

wait(100);

robot.turn(2500);

mystandup();
side_to_side();

robot.walk(-1500);
mystandup();
wait(500);
toTheFront();
robot.walk(1500);
mystandup();
wait(500);
toTheFront();

Chispun(3s) &
robot.turn(-3s);

upsidedown();
wait(1s);

legH1.val=0 time:1000 &
legH2.val=90 time:1000 &
legH3.val=90 time:1000;

loopn (2)
{
	timeout(1s) legLH3.val = 90 sin:200 ampli:15;
	wait(500);
};

wait(1000);
wagtail();

wait(10s);

descend();
 
},


at(speaker.remain=~=20000- 20500)
{
 global.ledMode=0;
 for(j=0;j<2;j++)
 {
  for(i=0;i<50;i++)
  {
   ledCabeza.val=1;
   wait(457);
   ledCabeza.val=0;
  };
  global.ledMode=1;
 }

},

/*
at(speaker.remain=~=10000)
{
 Luztravolta();
 Luztravolta2();
},


at(speaker.remain=~=13000)
{
 LucesCabeza(),
 moverorejas(),

},*/

at(speaker.remain=~= 10000)
{
	moverorejas();
},

}; // end events




// Main program
motor on;
Inicial();
at (headSensor > 10 ~ 500) 
{	
	ledHW.val=1;	
	speaker.play("techno.wav"),
	ledHW.val=0;
};